When I google the collation error I get lots of results that seem mostly to suggest server configuration issues. You could try changing the strored procedure used on that page as follows:
ALTER PROCEDURE [dbo].[mp_Users_SelectPage]
/*
Author: Joe Audette
Created: 2004-10-3
Last Modified: 2007-08-15
*/
@PageNumber int,
@PageSize int,
@UserNameBeginsWith nvarchar(50),
@SiteID int
AS
DECLARE @PageLowerBound int
DECLARE @PageUpperBound int
SET @PageLowerBound = (@PageSize * @PageNumber) - @PageSize
SET @PageUpperBound = @PageLowerBound + @PageSize + 1
--SET @PageLowerBound = @PageSize * @PageNumber
--SET @PageUpperBound = @PageLowerBound + @PageSize + 1
CREATE TABLE #PageIndexForUsers
(
IndexID int IDENTITY (1, 1) NOT NULL,
UserName nvarchar(50),
LoginName nvarchar(50)
)
IF @UserNameBeginsWith IS NULL OR @UserNameBeginsWith = ''
BEGIN
INSERT INTO #PageIndexForUsers (UserName, LoginName)
SELECT [Name], LoginName
FROM mp_Users
WHERE ProfileApproved = 1
AND DisplayInMemberList = 1
AND SiteID = @SiteID
AND IsDeleted = 0
ORDER BY [Name]
END
ELSE
BEGIN
INSERT INTO #PageIndexForUsers (UserName, LoginName)
SELECT [Name] , LoginName
FROM mp_Users
WHERE ProfileApproved = 1
AND DisplayInMemberList = 1
AND SiteID = @SiteID
AND IsDeleted = 0
AND [Name] COLLATE Latin1_General_CI_AS LIKE @UserNameBeginsWith + '%'
ORDER BY [Name]
END
DECLARE @TotalRows int
DECLARE @TotalPages int
DECLARE @Remainder int
SET @TotalRows = (SELECT Count(*) FROM #PageIndexForUsers)
SET @TotalPages = @TotalRows / @PageSize
SET @Remainder = @TotalRows % @PageSize
IF @Remainder > 0
SET @TotalPages = @TotalPages + 1
SELECT *,
'TotalPages' = @TotalPages
FROM mp_Users u
JOIN #PageIndexForUsers p
ON u.LoginName COLLATE Latin1_General_CI_AS = p.LoginName
WHERE u.ProfileApproved = 1
AND u.SiteID = @SiteID
AND u.IsDeleted = 0
AND p.IndexID > @PageLowerBound
AND p.IndexID < @PageUpperBound
ORDER BY p.IndexID
DROP TABLE #PageIndexForUsers
it may solve it for you and hopefully no other procedures need any changes.
Joe